Dicas  Excel Macros VBA
Inserir um gráfico no comentário

Pergunta 20:
Preciso inserir um gráfico no comentário, será que é possível???

Resposta 20:

Sim é possível, é um efeito muito bacana.!.
Esta macro pega o gráfico da plan1, e inseri no comentário na célula A1 da Plan1 forneça para macro o endereço, caminho correto do Gráfico

Sub Inseri_Image_Grafico_dentro_comentario_CelulaA1()

Dim nomImage As String
Dim Grph As ChartObject
Dim Hauteur As Single, Largeur As Single

nomImage = "C:\imageTemp.gif"

'Define sobre o gráfico dentro da Planilha Plan1
Set Grph = Plan1.ChartObjects(1)
'Exporte le graphique au format image GIF
Grph.Chart.Export nomImage, "GIF"

'recupera a dimensão do gráfico para aplicar no comentário
Hauteur = Grph.Height
Largeur = Grph.Width

'Verifica se já existe um comentário na celula A1
'e deleta se existe

If Not Plan1.Range("A1").Comment Is Nothing Then _
Plan1.Range("A1").Comment.Delete

'Criar um novo comentário na célula a1
With Plan1.Range("A1")
.AddComment
.Comment.Visible = False
'Define a altura do comentário
'do grafico
.Comment.Shape.Height = Hauteur
'Define a largura do comentário
.Comment.Shape.Width = Largeur
'Inseri a imagem dentro do comentário
.Comment.Shape.Fill.UserPicture nomImage
End With

'deleta a imagem exportada
Kill nomImage

'deleta o gráfico

Grph.Delete
End Sub